Creating first app for Android using Adobe Air

package
{
	import com.greensock.TweenMax;
	import com.greensock.easing.Cubic;
 
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
 
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.StageOrientationEvent;
	import flash.events.TransformGestureEvent;
 
	import flash.geom.Point;
 
	import flash.net.URLRequest;
	import flash.net.navigateToURL;
 
 
 
	/**
	 * Adobe AIR Android application example
	 *
	 * @author Piotr Koscierzynski, flashsimulations.com
	 *
	 * */
	[SWF(backgroundColor='0xf8f8f8',frameRate='31')]
	public class HelloAndroid extends Sprite
	{
		/* Android style components by Kevin Hoyt */
		private var superButton:Button;
		private var autoOrientCheckbox:CheckBox;
		private var footerLabel:Label;
 
		//
		private var uiCreated:Boolean = false;
 
		private var labels:Array = ['Click me!', "Welcome to Android world!", 'Life is like a box of chocolates.', 'Have a nice day.'];
		private var counter:uint = 0;
 
		private static const TWEEN_TIME:Number = 0.6;
		private var tweenFunction:Function = com.greensock.easing.Cubic.easeInOut;
 
		private var backgroundSprite:Sprite;
 
 
		public function HelloAndroid()
		{
			addEventListener(Event.ADDED_TO_STAGE, onAdded, false, 0, true);
		}
 
 
		private final function onAdded(e:Event):void {
 
			removeEventListener(Event.ADDED_TO_STAGE, onAdded);
 
			init();
		}
 
		/**
		 * Stage resize handler.
		 * */
		private final function onResize(e:Event = null):void {
 
			//no stage instance available
			if (!stage) return;
 
			//ui not instantiated
			if (!uiCreated) return;
 
			var stageWidth:uint = stage.stageWidth;
			var stageHeight:uint = stage.stageHeight;
 
			//background
			backgroundSprite.width = stageWidth;
			backgroundSprite.height = stageHeight;
			backgroundSprite.x = 0;
			backgroundSprite.y = 0;
 
 
 
			//checkbox position
			var autoOrientCheckbox_x:int = autoOrientCheckbox.width - 30;
			var autoOrientCheckbox_y:int =  10;
 
			TweenMax.killTweensOf(autoOrientCheckbox);
			TweenMax.to(autoOrientCheckbox, TWEEN_TIME, {x:autoOrientCheckbox_x, y: autoOrientCheckbox_y, ease:tweenFunction});
 
			//center the button
			superButton.setWidth(stageWidth - 20);
			var superButton_x:int = (stageWidth - superButton.width) >> 1;
			var superButton_y:int = (stageHeight - superButton.height) >> 1;
 
			TweenMax.killTweensOf(superButton);
			TweenMax.to(superButton, TWEEN_TIME, {x:superButton_x, y: superButton_y, ease:tweenFunction});
 
			var footerLabel_x:int = (stageWidth - footerLabel.width) >> 1;
			var footerLabel_y:int = (stageHeight - footerLabel.height - 10);
 
			TweenMax.killTweensOf(footerLabel);
			TweenMax.to(footerLabel, TWEEN_TIME, {x:footerLabel_x, y: footerLabel_y, ease:tweenFunction});
 
		}
 
		/**
		 * If the <autoOrients>true</autoOrients> tag is set to true then the application will receive this event.
		 * We can block the screen rotation by calling e.preventDefault().
		 *
		 * */
		private final function onOrientationChanging(e:StageOrientationEvent):void {
 
			//prevent the screen from rotating
			if (autoOrientCheckbox.selected == false)
			{
				e.preventDefault();
			}
		}
 
		/**
		 * Init stage align and listeners.
		 *
		 * */
		private final function init():void {
 
			buildUI();
 
			if (stage) {
 
				stage.align = StageAlign.TOP_LEFT;
				stage.scaleMode = StageScaleMode.NO_SCALE;
				stage.addEventListener(Event.RESIZE, onResize, false, 0, true);
				stage.addEventListener(StageOrientationEvent.ORIENTATION_CHANGING, onOrientationChanging, false, 0, true);
				stage.addEventListener(TransformGestureEvent.GESTURE_SWIPE, onSwipe, false, 0, true);
 
			}
 
 
			//set UI elements positions
			onResize();
 
		}
 
 
		/**
		 * Handle screen swipe - change the background of the screen.
		 *
		 * */
		private final function onSwipe(e:TransformGestureEvent):void {
 
 
				changeBgColor();
 
		}
 
		/**
		 * Build the user interface
		 * */
		private final function buildUI():void {
 
			//background
			backgroundSprite = new Sprite();
			backgroundSprite.graphics.beginFill(0xFFFFFF, 1);
			backgroundSprite.graphics.drawRect(0,0, 1, 1);
			backgroundSprite.graphics.endFill();
			backgroundSprite.mouseChildren = false;
			backgroundSprite.mouseEnabled = false;
			addChildAt(backgroundSprite, 0);
 
			//button
			superButton = new Button(labels[0], 300);
			superButton.addEventListener(MouseEvent.CLICK, handleButtonClick, false, 0, true);
			addChild(superButton);
 
 
			//checkbox - auto orientation enabled
			autoOrientCheckbox = new CheckBox('Auto orient screen');
			autoOrientCheckbox.selected = false;
			addChild(autoOrientCheckbox);
 
			//label for footer
			footerLabel = new Label('flashsimulations.com');
			footerLabel.addEventListener(MouseEvent.CLICK, handleFooterClick, false, 0, true);
			footerLabel.buttonMode = true;
			footerLabel.mouseChildren = false;
			addChild(footerLabel);
 
			uiCreated = true;
		}
 
		private function changeBgColor():void {
 
 
			TweenMax.to(backgroundSprite, 0.4, {tint:Math.random()*0xFFFFFF});
		}
 
		private final function handleButtonClick(e:Event):void {
			superButton.label = labels[(++counter)%labels.length];
			changeBgColor();
 
		}
 
		private final function handleFooterClick(e:Event):void {
			navigateToURL(new URLRequest('http://flashsimulations.com'));
		}
 
 
	}
}

<?xml version="1.0" encoding="utf-8" standalone="no"?>
<application xmlns="http://ns.adobe.com/air/application/2.5">
	<id>com.flashsimulations.air.HelloAndroid</id>
	<filename>HelloAndroid</filename>
	<name>Hello AndroAir</name>
	<versionNumber>1.0.0</versionNumber>
	<description>This application demonstrates the new Flash API for mobile devices (gestures, screen orientation). Created using Adobe AIR 2.5.</description>
	<copyright>Piotr Koscierzynski, flashsimulations.com</copyright>
	<supportedProfiles>mobileDevice</supportedProfiles>
 
	<!-- Settings for the application's initial window. Required. -->
	<initialWindow>
		<content>[This value will be overwritten by Flash Builder in the output app.xml]</content>
		<visible>true</visible>
		<autoOrients>true</autoOrients>
	</initialWindow>
 
	<android>
			<manifestAdditions>
			<![CDATA[ <manifest>
								<uses-permission android:name="android.permission.ACCESS_COARSE_LOCATION" />
								<uses-permission android:name="android.permission.ACCESS_FINE_LOCATION" />
								<uses-permission android:name="android.permission.ACCESS_NETWORK_STATE" />
								<uses-permission android:name="android.permission.ACCESS_WIFI_STATE" />
								<uses-permission android:name="android.permission.CAMERA" />
								<uses-permission android:name="android.permission.DISABLE_KEYGUARD" />
								<uses-permission android:name="android.permission.INTERNET" />
								<uses-permission android:name="android.permission.READ_PHONE_STATE" />
								<uses-permission android:name="android.permission.RECORD_AUDIO" />
								<uses-permission android:name="android.permission.WAKE_LOCK" />
								<uses-permission android:name="android.permission.WRITE_EXTERNAL_STORAGE" />
			</manifest>
			]]>
			</manifestAdditions>
	</android>
</application>